; Suborg's 14 bytes NASM modified version :
;Why did you call int 0x10 twice? Here's your pa!nt in just 14 bytes, source for nasm:
;Code:
BITS 16
mov al,0x12
mloop:
int 0x10
mov ax,0x03
int 0x33
xchg ax,bx
mov ah,0x0C
jmp mloop
;rulezadded on the 2013-10-22 13:16:57 by Suborg 

; HellMood's initial version :
; this is a "PA!NT" , a 16Byte DOS Demo
; written with NASM 
; it is tested with DOSBox 0.74
; if you use it, don't forget to trap the mouse
; in the DOSBox with CTRL + F10
; with two mouse buttons and a mouse wheel you
; are able to paint with up to seven colors
; left 			= blue
; right 		= green
; wheel 		= red
; left + right 		= cyan
; left + wheel 		= magenta
; right + wheel 	= brown
; left + right + wheel 	= white
; i didn't test a mouse with more buttons
; go ahead and try one, might be fun =)
; also, yes, if you don't press any mouse buttons
; you will paint "black" =(
; feel free to modify and improve "PA!NT" :)
;1.) If the mouse capture does not seem to work, try "CTRL + F10". This should command DOSBox to trap the mouse into the window =)
;2.) The cursor is invisible so far :/ You can spot it though, by holding (and then after spotting, releasing) a button without moving the mouse =)
;added on the 2013-10-22 02:54:28 by HellMood HellMood

org 100h
start:
mov al,0x12		; switch to 640*480 ( 16 colors )
			; is best for projecting mouse
int 0x10
mloop:
mov ax,0x03 		; get mouse position
int 0x33
			; CX holds x
			; CY holds y
			; BX holds button states
xchg ax,bx		; use button states as color	
mov ah,0x0C 		; set pixel ( on CX, DX )
int 0x10
dw 0xF4EB		; a 2byte "jmp mloop"